STM32F103を使ってみる

NTPクライアント


Arduino STM32 CoreにはF103シリーズ用にこ れらのライブラリが含まれています。
この中にはいくつかイーサネットライブラリが含まれています。
そこで、以下のライブラリを使ったNTPクライアントを紹介します。
Ethernet_STM
W5x00 ethernet library for STM32F103 micro-controllers

W5x00にはW5100/W5200/W5500などのチップが有り、これらを使ったモジュールとしては
W5100とW5500のモジュールが簡単に入手できます。
今回はW5500を使ったモジュールを使いました。
W5500チップを使ったWIZ550ioというMACアドレスを記憶できるモジュールもありますが少し高価です。


ピン数はどちらも8ピン仕様ですが、W5500は3.3Vでも使えます。


モジュールとの結線は以下の様になります。
W5x00 STM32F1
3.3V 3.3V(※1)
5V 5V(※1)
MISO PA6
MOSI PA7
SS PA4
SCLK PA5
GND GND
RST PullUp(※2)

(※1)
Blue Pill/Black Pillに実装されている5V→3.3VのレギュレータはRT9193-33(400mA) です。
W5500は 132mAで動きますが、Blue Pillの場合は5Vピンから給電した方が安定して動きます。
Black Pillの場合は5Vピンがないので、外部給電した方が安定して動きます。

(※2)
RSTは4.7Kの抵抗でPullUpする必要があります。これをしないと安定して動きません。
Arduinoでこのモジュールを使うときはRESETポート(電源投入時だけGNDに落ちてその後はPullUpするポート)に接続しますが、
STM32にはRESETポートがありません。
DHCPに接続できないときはRSTを一瞬、GNDに落としてやると繋がります。
GPIOに余裕があるときは、RSTを空いているGPIOにつないで、スケッチの最初で以下のPowerOnReset関数を実 行すると安定して 動きます。

void PowerOnReset(int pin) {
  pinMode(pin,OUTPUT);
  digitalWrite(pin,HIGH);
  delay(500);
  digitalWrite(pin,LOW);
  delay(500);
  digitalWrite(pin,HIGH);
  delay(500);
}

<追伸>
しばらく試しましたがRSTは4.7Kの抵抗でPullUpした方が安定して動きます。
</追伸>

こちらのArduinoのスケッチ をSTM32向けに移植しただけです。
Arduino用のスケッチが(ほぼそのまま)流用できるのがありがたいです。
UNOのEthernetライブラリにはDNSClientオブジェクトが有って、ホスト名→IPアドレスの名前解決ができるのですが、
STM32 Coreには(いまのところ)ありません。
/*

 Udp NTP Client for STM32F103 with W5x000 Module
 
 W5x00 <--> STM32F103 Pinout
 SS    <--> PA4 BOARD_SPI1_NSS_PIN
 SCK   <--> PA5 BOARD_SPI1_SCK_PIN
 MISO  <--> PA6 BOARD_SPI1_MISO_PIN
 MOSI  <--> PA7 BOARD_SPI1_MOSI_PIN
 5V    <--> 5V
 GND   <--> GND
 RST   <--> PA3(PowerOnReset)
 or
 RST   <--> 4.7KOhm <--> 5V

*/

#include <SPI.h>        
#include <Ethernet_STM.h> // https://github.com/rogerclarkmelbourne/Arduino_STM32
#include <EthernetUdp.h>  // https://github.com/rogerclarkmelbourne/Arduino_STM32
#include <TimeLib.h>      // https://github.com/PaulStoffregen/Time

// Enter a MAC address for your controller below.
// Newer Ethernet shields have a MAC address printed on a sticker on the shield
#if defined(WIZ550io_WITH_MACADDRESS) // Use assigned MAC address of WIZ550io
;
#else
byte mac[] = {0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED};
#endif 

unsigned int localPort = 8888;      // local port to listen for UDP packets
IPAddress timeServer(133, 243, 238, 164); // NTP Server

const int NTP_PACKET_SIZE= 48; // NTP time stamp is in the first 48 bytes of the message

byte packetBuffer[ NTP_PACKET_SIZE]; //buffer to hold incoming and outgoing packets

// A UDP instance to let us send and receive packets over UDP
EthernetUDP Udp;

// dow_char() 曜日文字を戻す [Sun,Mon....]
char * dow_char_EN(byte days) {
  char *you[] = {"Sun","Mon","Tue","Wed","Thu","Fri","Sat"};
  return you[days];
}

// dow_char() 曜日文字を戻す [日曜,火曜....]
char * dow_char_JP(byte days) {
  char *you[] = {"日曜","月曜","火曜","水曜","木曜","金曜","土曜"};
  return you[days];
}

// dow() 曜日を示す数値を戻す[0-Sunday, 1-Monday etc.]
uint8_t dow(unsigned long t) {
    return ((t / 86400) + 4) % 7;
}

void showTime(char * title, time_t timet, char * dow) {
   Serial.print(title);
   Serial.print(year(timet));
   Serial.print("/");
   Serial.print(month(timet));
   Serial.print("/");
   Serial.print(day(timet));
   Serial.print(" ");
   Serial.print(hour(timet));
   Serial.print(":");
   Serial.print(minute(timet));
   Serial.print(":");
   Serial.print(second(timet));
   Serial.print(" [");
   Serial.print(dow);
   Serial.println("]");
}

void PowerOnReset(int pin) {
  pinMode(pin,OUTPUT);
  digitalWrite(pin,HIGH);
  delay(500);
  digitalWrite(pin,LOW);
  delay(500);
  digitalWrite(pin,HIGH);
  delay(500);
}

void setup()
{
 // Open serial communications and wait for port to open:
  Serial.begin(9600);
  Serial.println("\n[NTP Client for EW5x00]");

  //PowerOnReset(PA3);  // Ethernet P.O.R

  // start Ethernet and UDP
#if defined(WIZ550io_WITH_MACADDRESS)
  if (Ethernet.begin() == 0) {
#else
  if (Ethernet.begin(mac) == 0) {
#endif 
    Serial.println("Failed to configure Ethernet using DHCP");
    // no point in carrying on, so do nothing forevermore:
    for(;;)
      ;
  }
  Serial.print("My IP: ");
  Serial.println(Ethernet.localIP());
  Serial.print("Netmask: ");
  Serial.println(Ethernet.subnetMask());
  Serial.print("GW IP: ");
  Serial.println(Ethernet.gatewayIP());
  Serial.print("DNS IP: ");
  Serial.println(Ethernet.dnsServerIP());

#if defined(WIZ550io_WITH_MACADDRESS)
  byte mac_address[6] ={0,};
  W5100.getMACAddress(mac_address);
  Serial.print("MAC: ");
  for(int i = 0; i < 6; i++) {
    Serial.print("0x");
    Serial.print(mac_address[i],HEX);
    Serial.print(" ");
  }
  Serial.println();
#endif

#if 0
  // タイムサーバーの名前解決
  DNSClient dns;
  dns.begin(Ethernet.dnsServerIP());
//  if(dns.getHostByName("ntp.jst.mfeed.ad.jp",timeServer) == 1) {
  if(dns.getHostByName("ntp.nict.jp",timeServer) == 1) {
    Serial.print(F("ntp = "));
    Serial.println(timeServer);
  } else {
    Serial.print(F("dns lookup failed"));
    while(1) { }
  }
#endif
   
  Udp.begin(localPort);
}

void loop()
{
  sendNTPpacket(timeServer); // send an NTP packet to a time server

  // wait to see if a reply is available
  delay(1000); 
  if ( Udp.parsePacket() ) { 
    Serial.println();
    // We've received a packet, read the data from it
    Udp.read(packetBuffer,NTP_PACKET_SIZE);  // read the packet into the buffer

    //the timestamp starts at byte 40 of the received packet and is four bytes,
    // or two words, long. First, esxtract the two words:

    unsigned long highWord = word(packetBuffer[40], packetBuffer[41]);
    unsigned long lowWord = word(packetBuffer[42], packetBuffer[43]); 
    // combine the four bytes (two words) into a long integer
    // this is NTP time (seconds since Jan 1 1900):
    unsigned long secsSince1900 = highWord << 16 | lowWord; 
    Serial.print("Seconds since Jan 1 1900 = " );
    Serial.println(secsSince1900);              

    // now convert NTP time into everyday time:
    // Unix time starts on Jan 1 1970. In seconds, that's 2208988800:
    const unsigned long seventyYears = 2208988800UL;    
    // subtract seventy years:
    unsigned long epoch = secsSince1900 - seventyYears; 
    // print Unix time:
    Serial.print("Unix time = ");
    Serial.println(epoch);                              

#if 0
    // print the hour, minute and second:
    Serial.print("The UTC time is ");       // UTC is the time at Greenwich Meridian (GMT)
    Serial.print((epoch  % 86400L) / 3600); // print the hour (86400 equals secs per day)
    Serial.print(':'); 
    if ( ((epoch % 3600) / 60) < 10 ) {
      // In the first 10 minutes of each hour, we'll want a leading '0'
      Serial.print('0');
    }
    Serial.print((epoch  % 3600) / 60); // print the minute (3600 equals secs per minute)
    Serial.print(':');
    if ( (epoch % 60) < 10 ) {
      // In the first 10 seconds of each minute, we'll want a leading '0'
      Serial.print('0');
    }
    Serial.println(epoch %60); // print the second
#endif

    // グリニッジ標準時間
    uint8_t DayOfWeek = dow(epoch);
    showTime("The UTC time is ", epoch, dow_char_EN(DayOfWeek));
    // 日本標準時にあわせるために+9時間しておく
    DayOfWeek = dow(epoch + (9 * 60 * 60));
    showTime("The JST time is ", epoch + (9 * 60 * 60), dow_char_JP(DayOfWeek));
  } else {
    Serial.println("We waiting a packet");
  }
  // wait ten seconds before asking for the time again
  delay(10000);
}

// send an NTP request to the time server at the given address
unsigned long sendNTPpacket(IPAddress& address)
{
  // set all bytes in the buffer to 0
  memset(packetBuffer, 0, NTP_PACKET_SIZE);
  // Initialize values needed to form NTP request
  // (see URL above for details on the packets)
  packetBuffer[0] = 0b11100011;   // LI, Version, Mode
  packetBuffer[1] = 0;     // Stratum, or type of clock
  packetBuffer[2] = 6;     // Polling Interval
  packetBuffer[3] = 0xEC;  // Peer Clock Precision
  // 8 bytes of zero for Root Delay & Root Dispersion
  packetBuffer[12]  = 49;
  packetBuffer[13]  = 0x4E;
  packetBuffer[14]  = 49;
  packetBuffer[15]  = 52;

  // all NTP fields have been given values, now
  // you can send a packet requesting a timestamp:           
  Udp.beginPacket(address, 123); //NTP requests are to port 123
  Udp.write(packetBuffer,NTP_PACKET_SIZE);
  Udp.endPacket();
}

シリアルモニターには以下の様に表示されます。


次回はW5500のEthernetモジュールを使ったSocket通信を紹 介しま す。

続く...